Process

Process, Cmd, PID-or-Name [, Param3]

; Пример №1

Run Notepad.exe, , , NewPID
Process, priority, %NewPID%, High
MsgBox Процесс Блокнота имеет идентификатор %NewPID%.

; Пример №2

Process, wait, Notepad.exe, 5.5
NewPID = %ErrorLevel% ; Сразу сохранить значение, т.к. ErrorLevel часто изменяется.
if NewPID = 0
{
    MsgBox Указанный процесс не появился в течение 5.5 секунд.
    return
}
; Иначе
MsgBox Появился подходящий процесс (его идентификатор %NewPID%).
Process, priority, %NewPID%, Low
Process, priority, , High ; Установить приоритет процесса скрипта в High (высокий).
WinClose Безымянный - Блокнот
Process, WaitClose, %NewPID%, 5
if ErrorLevel ; Если PID ещё существует.
    MsgBox Процесс не завершился в течение 5 секунд.

; Пример №3: горячая клавиша для изменения приоритета процесса активного окна.

#z:: ; Комбинация Win+Z.
WinGet, active_pid, PID, A
WinGetTitle, active_title, A
Gui, 5:Add, Text,, Нажмите Esc для отмены или дважды щёлкните новый`nуровень приоритета для следующего окна:`n%active_title%
Gui, 5:Add, ListBox, vMyListBox gMyListBox r5, Normal|High|Low|BelowNormal|AboveNormal
Gui, 5:Add, Button, default, OK
Gui, 5:Show,, Установка приоритета
return

5GuiEscape:
5GuiClose:
Gui, Destroy
return

MyListBox:
if A_GuiEvent <> DoubleClick
    return
; Иначе перейти к следующей метке:
5ButtonOK:
GuiControlGet, MyListBox
Gui, Destroy
Process, Priority, %active_pid%, %MyListBox%
if ErrorLevel
    MsgBox Успех: приоритет заменён на "%MyListBox%".
else
    MsgBox Ошибка: приоритет не может быть заменён на "%MyListBox%".
return

; Пример №4: составляет список выполняющихся процессов через DllCall и показывает его в MsgBox.

d = `n ; разделитель строк
s := 4096 ; размер буферов и массивов (4 KB)

Process, Exist ; Устанавливает значение перем. ErrorLevel равным идентификатору процесса текущего скрипта
; Получает дескриптор (handle) этого скрипта через PROCESS_QUERY_INFORMATION (0x0400)
h := DllCall("OpenProcess", "UInt", 0x0400, "Int", false, "UInt", ErrorLevel)
; Открывает регулируемый маркер доступа (adjustable access token) этого процесса
; (TOKEN_ADJUST_PRIVILEGES = 32)
DllCall("Advapi32.dll\OpenProcessToken", "UInt", h, "UInt", 32, "UIntP", t)
VarSetCapacity(ti, 16, 0) ; структура полномочий
InsertInteger(1, ti, 0, 4) ; один элемент в массиве полномочий...
; Извлекает локальный уникальный идентификатор полномочий на отладку:
DllCall("Advapi32.dll\LookupPrivilegeValueA", "UInt", 0, "Str", "SeDebugPrivilege", "UIntP", luid)
InsertInteger(luid, ti, 4, 8)
InsertInteger(2, ti, 12, 4) ; включает это полномочие: SE_PRIVILEGE_ENABLED = 2
; Обновляет полномочия этого процесса новым маркером доступа:
DllCall("Advapi32.dll\AdjustTokenPrivileges"
, "UInt", t, "Int", false, "UInt", &ti, "UInt", 0, "UInt", 0, "UInt", 0)
DllCall("CloseHandle", "UInt", h) ; закрывает данный дескриптор процесса для экономии памяти

; увеличиваем производительность, предварительно загружая библиотеку:
hModule := DllCall("LoadLibrary", "Str", "Psapi.dll")
s := VarSetCapacity(a, s) ; массив, который получает список идентификаторов процессов
DllCall("Psapi.dll\EnumProcesses", "UInt", &a, "UInt", s, "UIntP", r)
Loop, % r // 4 ; производим разбор массива для таких идентификаторов, как DWORDs (32 bits):
{
   id := ExtractInteger(a, A_Index * 4)
   ; Открываем процесс с помощью: PROCESS_VM_READ (0x0010) | PROCESS_QUERY_INFORMATION (0x0400)
   h := DllCall("OpenProcess", "UInt", 0x0010 | 0x0400, "Int", false, "UInt", id)
   VarSetCapacity(m, s) ; массив, который получает список дескрипторов модулей:
   DllCall("Psapi.dll\EnumProcessModules", "UInt", h, "UInt", &m, "UInt", s, "UIntP", r)
   VarSetCapacity(n, s, 0) ; буфер, который получает базовое имя модуля:
   e := DllCall("Psapi.dll\GetModuleBaseNameA", "UInt", h, "UInt", m, "Str", n, "Chr", s)
   DllCall("CloseHandle", "UInt", h) ; закрываем дескриптор процесса для экономии памяти
   If n ; если образ не null, добавляем в список:
      l = %l%%n%%d%
}
DllCall("FreeLibrary", "UInt", hModule) ; выгружаем библиотеку, чтобы освободить память
; стираем первый и последний пункт списка (возможно, сигнатуры ASCII)
StringMid, l, l, InStr(l, d) + 1, InStr(l, d, false, 0) - 2 - InStr(l, d)
StringReplace, l, l, %d%, %d%, UseErrorLevel ; извлекаем число процессов
;Sort, l, C ; уберите комментарий с этой строки, чтобы отсортировать список в алфавитном порядке
MsgBox, 0, %ErrorLevel% процессов, %l%

ExtractInteger(ByRef pSource, pOffset = 0, pIsSigned = false, pSize = 4) ; см. описание DllCall
{
    Loop %pSize% ; собираем целое число, складывая его байты.
        result += *(&pSource + pOffset + A_Index-1) << 8*(A_Index-1)
    if (!pIsSigned OR pSize > 4 OR result < 0x80000000)
        return result ; в этих случаях не имеет значения, со знаком число или без
    return -(0xFFFFFFFF - result + 1)
}

InsertInteger(pInteger, ByRef pDest, pOffset = 0, pSize = 4)
{
    Loop %pSize% ; копируем каждый байт целого числа в структуру как сырые двоичные данные
        DllCall("RtlFillMemory", "UInt", &pDest + pOffset + A_Index-1
        , "UInt", 1, "UChar", pInteger >> 8*(A_Index-1) & 0xFF)
}